blob: 238888ada60f0b2a715c1552c89aaa0b3ac9cfae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Antonio Rojas <arojas@archlinux,org>
# Maintainer: Felix Yan <[email protected]>
# Contributor: Andrea Scarpino <[email protected]>
# Contributor: Pierre Schmitz <[email protected]>
pkgname=dolphin
pkgver=19.12.3
pkgrel=2
pkgdesc="KDE File Manager"
arch=(x86_64)
url="https://kde.org/applications/system/dolphin/"
license=(LGPL)
depends=(baloo-widgets knewstuff kio-extras kcmutils kparts kinit phonon-qt5)
makedepends=(extra-cmake-modules kdoctools)
optdepends=('kde-cli-tools: for editing file type options' 'ffmpegthumbs: video thumbnails' 'kdegraphics-thumbnailers: PDF and PS thumbnails'
'konsole: terminal panel' 'purpose: share context menu')
groups=(kde-applications kdebase)
source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
kdebug-419585.patch::"https://cgit.kde.org/dolphin.git/patch/?id=35b4c6d4")
sha256sums=('ba16f4d5be5ccc3c135a913f2e3c7dd3b7a492cfc9ec9ae518f714fcd7c2ab47'
'SKIP'
'da74a881d092c67a7c6cf63f06facac8037640f139b1520efd5bea97f49b8d65')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <[email protected]>
F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <[email protected]>
prepare() {
mkdir -p build
cd $pkgname-$pkgver
patch -p1 -i ../kdebug-419585.patch # Fix crash with Qt 5.14.2
}
build() {
cd build
cmake ../$pkgname-$pkgver \
-DBUILD_TESTING=OFF
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|
